Удобная вставка текста в текстовые поля кнопки

Это первый пост, потому хочется начать с чего-нибудь простого. Расскажу о функции, которая сильно упрощает мне жизнь при создании GUI.

Лирическое вступление

Для формирования сложного GUI (например игрового) я почти всегда использую следующий способ: GUI формируется в fla файле (каждое окно — отдельный класс), всем кнопкам, текстовым полям и тп прописываются instance name, а затем окно или несколько экспортируется в swc, которые подключаются к проекту (например FlashDevelop), пишутся классы наследованные от классов втянутых из swc в которых я уже вношу текст на кнопки, привязываю обработчики событий, и вообще из шаблона делаю собственно GUI. Делая так я имею возможность импортировать макеты окон прямо из PSD файлов и быстро подключать их к проекту. Уверен что этот прием известен большинству flash-разработчиков, потому продолжим (если есть необходимость в статье об этом — скажите).

Первая проблема

В процессе написания класса окна унаследованного от класса из swc часто возникает необходимость просто и быстро вписать текст в текстовое поле, являющее дочерним объектом не для самого окна, а например обернутое в один или несколько MovieClip-ов. Обычно такая ситуация решается одним из трех способов:

1. разработчик возвращается во fla файл и убирает ненужные обертки (часто этот способ самый правильный, хоть не всегда возможный)
   
2. разработчик использует методы getChildAt, getChildByName
   В результате присвоение текста выглядит примерно так
   

   (((myWindow.getChildByName('myChildMovie') as Sprite).
                   getChildAt(0) as Sprite).
                                   getChildByName('myTextfield') as Textfield).text='текст';

   или и вовсе
   

   myWindow.getChildByName('myChildMovie').getChildAt(0).
                                           getChildByName('myTextfield').text='текст';

   Это наиболее некрасивый и глючный способ.
3. разработчик для доступа к вложенному текстовому полю возвращается во fla и присваивает Class Name и Instance Name каждому вложенному MovieClip находящемуся в иерархии сцены между окном и текстовым полем а также Instance Name самому текстовому полю. В результате присвоение текста выглядит так
   

   myWindow.myChildMovie.mySubChildMovie.myTextfield.text='текст';

   
   Этот способ довольно громоздкий но в целом не плохой

Вторая проблема

Допустим в классе окна есть несколько дочерних кнопок, у которых в каждом состоянии есть динамическое текстовое поле, нам нужно каждой кнопке присвоить текст таким образом, чтобы он прописался во все текстовые поля состояний кнопки.
Обычно это делается примерно так:

myButton.upState.getChildByName('myTextField').text="текст на кнопке";
myButton.overState.getChildAt(0).text="текст на кнопке";
myButton.downState.getChildByName('myTextField').text="текст на кнопке";

что не красиво и не эффективно

Решение

Представленная функция берет переданный ей DisplayObject и пробегает рекурсивно все его дочерние DisplayObject и каждому найденному текстовому полю присваивает переданный ей текст.
параметр _mc: DisplayObject, это может быть кнопка с текстовыми полями, MovieClip с глубоко внутри запрятанным текстовым полем или даже само текстовое поле.
параметр _text: String, строка которую нужно присвоить текстовым полям.

public static function setTextToAllTextfields(_mc : DisplayObject,_text : String) : void
{
        if (_mc is TextField)
        {
                var tf : TextField = _mc as TextField;
                var format : TextFormat;
                if (tf.text.length>0)
                {
                        format = tf.getTextFormat(0, tf.text.length);
                } else 
                {
                        format = tf.getTextFormat();
                }
                tf.text = _text;
                // Это сделано для того чтобы после смены текста не исчезал TextFormat 
                //созданный через настройки текстового поля во Flash
                tf.setTextFormat(format);
        }

        if (_mc is DisplayObjectContainer)
        {
                var mc : DisplayObjectContainer = _mc as DisplayObjectContainer;

                for (var x : int = 0; x < mc.numChildren; ++x)
                {
                        var child : DisplayObject = mc.getChildAt(x);
                        setTextToAllTextfields(child, _text);
                }
        }

        if (_mc is SimpleButton)
        {
                var btn : SimpleButton = _mc as SimpleButton;
                setTextToAllTextfields(btn.upState, _text);
                setTextToAllTextfields(btn.overState, _text);
                setTextToAllTextfields(btn.downState, _text);
        }
}

Пример использования:

setTextToAllTextfields(myMovieClip,'Текст для всех вложеных текстовых полей');
setTextToAllTextfields(myButton,'Текст для всех состояний кнопки');
setTextToAllTextfields(myTextFileld,'Текст для текстового поля');

Кроме того, если во Flash динамическому текстовому полю был присвоен параметр «жирный» то простое присвоение текста через поле .text эту жирность уберет. Используя эту функцию этой проблемы удасться избежать, то есть имеет смысл использовать ее и для присваивания текста в текстовое поле.

Заключение

Удобно? Я считаю да. Но за все приходится платить и платим мы быстродействием. Потому не стоит применять эту функцию в узких местах программы. Однако открытие окна обычно узким местом не является и потому относительно медленное выполнение вставки текста не приведет к сколько-нибудь заметному подтормаживанию.

Согласно пункту 6 правил даю ссылку на эту статью на моем блоге.

Спасибо за внимание!