Hello, Keyboard!

Движение с постоянной скоростью.

import flash.display.Sprite;
import flash.events.Event;
import flash.events.KeyboardEvent;
import flash.ui.Keyboard;
import flash.geom.Point;

stage.frameRate = 30;

// Это наш ГэГэ. Он может перемещаться как в
// горизонтальном, так и вертикальном направлениях.
var _gg:Sprite;

// Модуль скорости движения.
var _velValue:Number = 3.0;

// Направление, задаваемое игроком.
var _direction:Point = new Point();

// А тут у нас вспомогательные переменные, для работы с клавой.
var _keyL:Boolean = false;
var _keyR:Boolean = false;
var _keyU:Boolean = false;
var _keyD:Boolean = false;

// Рисуем демо сцену
createDemoScene();

// Слушаем необходимые события.
stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);

/** Рисуем простенькую демо сцену. */
function createDemoScene():void
{
        _gg = new Sprite();
        _gg.graphics.beginFill(0xff3300);
        _gg.graphics.drawCircle(0, 0, 10);
        _gg.graphics.endFill();
        
        _gg.x = stage.stageWidth / 2;
        _gg.y = stage.stageHeight / 2;
        addChild(_gg);
}

/** Весь движняк, как обычно. */
function onEnterFrame(event:Event):void
{
        // Вычисляем скорость на основании вектора направления.
        var velocity:Point = _direction.clone();
            velocity.normalize(_velValue);

        // И, собственно, движемся в заданном направлении.
        _gg.x += velocity.x;
        _gg.y += velocity.y;
}

/** Когда наступили на кнопочку на клавиатуре.
    Обрабатываются сразу стрелочки и WASD.

    Здесь все просто: куда только что нажали,
    туда мы и летим. Таким образом здесь у нас
    организован приоритет последней нажатой
    кнопки */
function onKeyDown(event:KeyboardEvent):void
{
        switch (event.keyCode)
        {
                case Keyboard.LEFT:
                case Keyboard.A:
                        _keyL = true;
                        _direction.x = -1;
                        break;
                case Keyboard.RIGHT:
                case Keyboard.D:
                        _keyR = true;
                        _direction.x = 1;
                        break;
                case Keyboard.UP:
                case Keyboard.W:
                        _keyU = true;
                        _direction.y = -1;
                        break;
                case Keyboard.DOWN:
                case Keyboard.S:
                        _keyD = true;
                        _direction.y = 1;
                        break;
        }
}

/** Когда кнопочку отпустили, соответственно.
    
    Здесь же при отпускании одной из парных
    кнопок (пары вправо-влево и вверх-вниз)
    мы проверяем, не нажата ли в это время
    вторая кнопка из пары. */
function onKeyUp(event:KeyboardEvent):void
{
        switch (event.keyCode)
        {
                case Keyboard.LEFT:
                case Keyboard.A:
                        _keyL = false;
                        _direction.x = _keyR ? 1 : 0;
                        break;
                case Keyboard.RIGHT:
                case Keyboard.D:
                        _keyR = false;
                        _direction.x = _keyL ? -1 : 0;
                        break;
                case Keyboard.UP:
                case Keyboard.W:
                        _keyU = false;
                        _direction.y = _keyD ? 1 : 0;
                        break;
                case Keyboard.DOWN:
                case Keyboard.S:
                        _keyD = false;
                        _direction.y = _keyU ? -1 : 0;
                        break;
        }
}

Движение с ускорением.

import flash.display.Sprite;
import flash.events.Event;
import flash.events.KeyboardEvent;
import flash.ui.Keyboard;
import flash.geom.Point;

stage.frameRate = 30;

// Это наш ГэГэ. Он может перемещаться как в
// горизонтальном, так и вертикальном направлениях.
var _gg:Sprite;

// Неизменная величина ускорения.
var _accValue:Number = 1.0;

// Сопротивление окружающей среды, чтобы кораблик останавливался.
var _envResistance:Number = 0.9;

// Тут будем хранить вектор скорости.
var _velocity:Point = new Point();

// Направление, задаваемое игроком.
var _direction:Point = new Point();

// А тут у нас вспомогательные переменные, для работы с клавой.
var _keyL:Boolean = false;
var _keyR:Boolean = false;
var _keyU:Boolean = false;
var _keyD:Boolean = false;

// Рисуем демо сцену
createDemoScene()

// Слушаем необходимые события.
stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);

/** Рисуем простенькую демо сцену. */
function createDemoScene():void
{
        _gg = new Sprite();
        _gg.graphics.beginFill(0xff3300);
        _gg.graphics.drawCircle(0, 0, 10);
        _gg.graphics.endFill();
        
        _gg.x = stage.stageWidth / 2;
        _gg.y = stage.stageHeight / 2;
        addChild(_gg);
}

/** Весь движняк, как обычно. */
function onEnterFrame(event:Event):void
{
        // Вычисляем теперь уже ускорение на основании
        // вектора направления.
        var acceleration:Point = _direction.clone();
            acceleration.normalize(_accValue);

        // Ускоряемся.
        _velocity = _velocity.add(acceleration);
        
        // Испытываем сопротивление среды
        _velocity.x *= _envResistance;
        _velocity.y *= _envResistance;
        
        // И наконец движемся
        _gg.x += _velocity.x;
        _gg.y += _velocity.y;
}

/** Когда наступили на кнопочку на клавиатуре. */
function onKeyDown(event:KeyboardEvent):void
{
        switch (event.keyCode)
        {
                case Keyboard.LEFT:
                case Keyboard.A:
                        _keyL = true;
                        _direction.x = -1;
                        break;
                case Keyboard.RIGHT:
                case Keyboard.D:
                        _keyR = true;
                        _direction.x = 1;
                        break;
                case Keyboard.UP:
                case Keyboard.W:
                        _keyU = true;
                        _direction.y = -1;
                        break;
                case Keyboard.DOWN:
                case Keyboard.S:
                        _keyD = true;
                        _direction.y = 1;
                        break;
        }
}

/** Когда кнопочку отпустили, соответственно. */
function onKeyUp(event:KeyboardEvent):void
{
        switch (event.keyCode)
        {
                case Keyboard.LEFT:
                case Keyboard.A:
                        _keyL = false;
                        _direction.x = _keyR ? 1 : 0;
                        break;
                case Keyboard.RIGHT:
                case Keyboard.D:
                        _keyR = false;
                        _direction.x = _keyL ? -1 : 0;
                        break;
                case Keyboard.UP:
                case Keyboard.W:
                        _keyU = false;
                        _direction.y = _keyD ? 1 : 0;
                        break;
                case Keyboard.DOWN:
                case Keyboard.S:
                        _keyD = false;
                        _direction.y = _keyU ? -1 : 0;
                        break;
        }
}