Framework: State & StateManager

Как работает мой игровой фреймворк? В основе всего лежит State и управляющий им StateManager.

State

elmortem.states.State
Наследуется от Sprite и реализует в своих наследниках логику игровых экранов. Например от него наследуются классы Mainmenu, Gameplay, Options и т.д.
Конструктор принимает не обязательный Object, который сохраняется в публичном параметре attr. Это позволяет передавать игровым экранам любое количество параметров любого типа и является универсальным. Такой метод передачи параметров используется почти во всех моих объектах.

StateManager

elmortem.states.StateManager
Этот класс управляет игровыми экранами. Он добавляет их на сцену, инициализирует, удаляет. Экземпляр этого класса является статическим параметром моего основного класса Main, который либо является DocumentClass'ом, либо создаётся в Preloader'е.
Конструктор принимает Object с пока единственным свойством clip — сцена, в которую будут добавляться игровые экраны.

Выглядит это примерно так:

// Document Class
class Main extends Sprite {
  static public var stateManager:StateManager;

  public function Main() {
    if(stage) init();
    else addEventListener(Event.ADDED_TO_STAGE, init);
  }
  private function init(e:Event = null):void {
    stateManager = new StateManager({clip:this});
    // clip - сцена, куда будут добавляться экраны
    
    stateManager.show(new Mainmenu());
  }
}
// MAINMENU
public class Mainmenu extends State {
  public function Mainmenu(attrIn:Object = null) {
    super(attrIn);
  }
  override protected function init():void {
    // вызывается после ADDED_TO_STAGE, реализовано в State
    addEventListener(MouseEvent.CLICK, onClick);
  }
  override public function free():void {
    // free - единое для всех моих объектов название метода удаления объекта
    // После вызова этого метода объект использовать нельзя
    removeEventListener(MouseEvent.CLICK, onClick);
  }
  private function onClick(e:MouseEvent):void {
    Main.stateManager.show(new Gameplay({map:1}));
  }
}
// GAMEPLAY
public class Gameplay extends State {
  public function Gameplay(attrIn:Object = null) {
    super(attrIn);
  }
  override protected function init():void {
    trace("Map "+attr.map);
    addEventListener(MouseEvent.CLICK, onClick);
  }
  override public function free():void {
    removeEventListener(MouseEvent.CLICK, onClick);
  }
  private function onClick(e:MouseEvent):void {
    Main.stateManager.show(new Mainmenu());
  }
}

Продолжение следует...